100 DIM dir$(50,16)
110 CLS
120 CSIZE 2,0
130 PRINT "INSERT CARTRIDGE TO BE COPYED IN"
140 PRINT "DRIVE 1 AND CARTRIDGE TO BE COPYED"
150 PRINT "INTO DRIVE 2"
160 PRINT
170 INPUT "IS OUTPUT CARTRIDGE TO BE FORMATTED?"!ans$
180 ans$=ans$(1)
190 form = ans$ INSTR "NY"
200 IF form = 0 THEN PRINT "ANSWER Y,y,N or n": GO TO 170
210 IF form=2 THEN 
220 INPUT "WHAT IS THE NAME OF OUTPUT CARTRIDGE?"!ans$
230 FLASH 1:PRINT "formatting":FLASH 0
240 REPeat f
250 FORMAT "mdv2_"&ans$
260 IF INKEY$(-1)=" " THEN EXIT f
270 END REPeat f
280 END IF 
290 CLS:AT 18,0
300 CLOSE #2:OPEN_NEW #2,pipe_1000
310 DIR #2,mdv1_
320 OPEN_NEW #3,pipe_0
330 CLOSE #2:OPEN #2,scr_448x200:INK #2,7
340 no_recs=0
350 FOR i=0 TO 50
360 IF EOF(#3) THEN EXIT i
370 INPUT #3,dir$(i)
380 PRINT dir$(i)
390 no_recs=i
400 END FOR i
410 CLOSE #3
420 PRINT
430 PRINT "ANSWER 'A' TO COPY REST OF FILES"
440 PRINT:PRINT
450 ans$=""
460 FOR i=2 TO no_recs
470 PRINT dir$(i)
480 IF ans$=="A" THEN GO TO 530
490 AT 19,18:INPUT "COPY FILE?";ans$
500 AT 19,18:PRINT FILL$(" ",18)
510 IF ans$=="N" THEN GO TO 570
520 IF ans$=="Y" OR ans$=="A" THEN GO TO 530:ELSE GO TO 490
530 AT 19,18:FLASH 1:PRINT "copying file"
540 DELETE "mdv2_"&dir$(i)
550 COPY "mdv1_"&dir$(i),"mdv2_"&dir$(i)
560 AT 19,18:FLASH 0:PRINT "copied      "
570 END FOR i
580 PRINT
590 PRINT "END OF COPY"
