100 IF NOT EOF THEN scr_prt=RESPR(521):LBYTES mdv2_gprint_prt,scr_prt:BAUD 1200
110 RESTORE :DIM no_days(12),month$(12,10)
120 j=0:FOR i=1 TO 12:no_days(i)=j:READ k,month$(i):j=j+k
130 INPUT #0,"Enter birth date  Day?"!b_dd,"Month?"!b_mm,"Year?"!b_yy
140 c_mm=b_mm:c_yy=b_yy
150 PRINT #0,"<SPACE> to select a month"\"<UP>    for previous month","<DOWN> for next month"
160 PRINT #0,"<P>     to print",,"<ESC>  to exit"
170 REPeat action
180 key=CODE(INKEY$(-1))
190 SELect ON key
200 =27:EXIT action
210 =32:INPUT #0,"Enter current date  Month?"!c_mm,"Year?"!c_yy
220 =208:c_mm=c_mm-1:IF c_mm=0 THEN c_mm=12:c_yy=c_yy-1
230 =216:c_mm=c_mm+1:IF c_mm=13 THEN c_mm=1:c_yy=c_yy+1
240 =80,112:CALL scr_prt:BEEP 4000,0
250 =REMAINDER :NEXT action
260 END SELect 
270 SCALE 4,-5E-2,-2.5:PAPER 0:CLS:CSIZE 1,1:INK 0:STRIP 2
280 AT 0,0:PRINT " Born:"!b_dd;"/";b_mm;"/";b_yy;" "
290 AT 0,33:PRINT " Date:"!month$(c_mm)!c_yy;" "
300 CSIZE 0,0:INK 2:LINE 0,0 TO 6.1,0
310 FOR i=0 TO 6 STEP .2:INK 2:LINE i,0 TO i,-.1:CURSOR i,0,-3,3:INK 0:PRINT i*5+1
320 n=days(1,c_mm,c_yy)-days(b_dd,b_mm,b_yy)
330 plot n,33,68,"@ Intellectual:"
340 plot n,28,90,"* Emotional:"
350 plot n,23,112,"+ Physical:"
360 CLS #0
370 END REPeat action
380 DEFine PROCedure plot(n,cyl,lin,name$)
390 LOCal i,j,k,mul,cyl2
400 cyl2=INT(cyl/2):mul=2*PI/cyl:k=n MOD cyl:j=mul*k
410 INK 0:CSIZE 1,0:CURSOR 0,0,-3,lin-9:PRINT !name$:INK 7:OVER 1:LINE 0,SIN(j)
420 FOR i=0 TO 6 STEP .2
430 REMark LINE TO i,SIN(j+mul*5*i):CURSOR i,0,-3,lin
440 CURSOR i+.1,SIN(j+mul*5*(i+.1)),-3,-5:PRINT name$(1)
450 CURSOR i,SIN(j+mul*5*i),-3,-5:PRINT name$(1):CURSOR i,0,-3,lin
460 IF k=0 OR k=cyl2 THEN PRINT "C";:ELSE IF k>cyl2 THEN PRINT "-";:ELSE PRINT "+";
470 k=(k+1) MOD cyl
480 END FOR i
490 OVER 0:CSIZE 0,0
500 END DEFine 
510 DEFine FuNction days(dd,mm,yy)
520 LOCal n
530 n=no_days(mm)
540 IF mm>2 AND yy MOD 4>0 THEN n=n-1
550 RETurn dd+n+INT((yy MOD 100-1)*365.25)
560 END DEFine 
570 DATA 31,"January",29,"Feburary",31,"March",30,"April",31,"May",30,"June"
580 DATA 31,"July",31,"August",30,"September",31,"October",30,"November",31,"December"
