1 MODE 0:OVER 0
2 OPEN #3,scr_512x256a0x0:PAPER #3,4:CLS #3
3 OPEN #4,scr_445x195a45x28:PAPER #4,0:CLS #4
4 PAPER 7,2,1:CLS:SCALE 200,0,0
5 FILL 1:write:sky
6 FILL 1:INK 2:CIRCLE 30,130,50
7 FILL 1:INK 4:LINE 0,100 TO 400,100 TO 400,0 TO 0,0 TO 0,100
8 FILL 0:INK 0
9 ground:mount:c=2:BORDER 1,0
10 FOR n=0 TO 152 STEP .5
11 n1=n/1.5
12 x=n1+n1*COS(n/104*PI)
13 a=n1+n1*SIN(n/52*PI)
14 b=n1-n1*COS(n/(26+x)*PI)
15 FILL 1:INK c:CIRCLE 100+(a-n1),100+(b-n1),n/8
16 FILL 0:INK 0:CIRCLE 100+(a-n1),100+(b-n1),n/8
17 c=(2*(c=4))+(4*(c=2))
18 END FOR n
19 FILL 1:INK 7:CIRCLE 110,160,15,.8,RAD(0)
20 FILL 0:INK 0:CIRCLE 110,160,15,.8,RAD(0)
21 FILL 1:INK 7:CIRCLE 130,160,15,.8,RAD(0)
22 FILL 0:INK 0:CIRCLE 130,160,15,.8,RAD(0)
23 FILL 1:INK 0:CIRCLE 110,160,5,.8,RAD(0)
24 FILL 1:INK 0:CIRCLE 130,160,5,.8,RAD(0)
25 DEFine PROCedure mount
26 c=1
27 FOR loop=1 TO -5 STEP -1
28 c=(1*(c=3))+(3*(c=1))
29 FOR n=-30 TO 300 STEP 30
30 a=RND(1 TO (loop+6)*10)+10+10*SIN(n/100*PI)
31 b=RND(50 TO 100)
32 FILL 1:INK 2,0,c:LINE n,100+loop TO n+b/2,100+a+loop TO n+b,100+loop
33 FILL 0:INK 0:LINE n,100+loop TO n+b/2,100+a+loop TO n+b,100+loop
34 END FOR n
35 END FOR loop
36 END DEFine 
37 DEFine PROCedure ground
38 FOR n=0 TO 300 STEP 10:LINE n,100 TO n*10-1200,0
39 FOR n=100 TO 80 STEP -2:LINE 0,n-(100-n)*(100-n) TO 350,n-(100-n)*(100-n)
40 END DEFine 
41 DEFine PROCedure sky
42 c=7:FOR n=1 TO 400:INK c:POINT RND(n/2 TO 350),RND(100 TO 200):c=(c=7)*2+(c=2)*7
43 END DEFine 
44 DEFine PROCedure write
45 CSIZE #0,2,0:OVER #0,1
46 FOR n=1 TO 8:CURSOR #0,60-n,20-n:INK #0,n:PRINT #0,"Dedicated to 'NEW AGE' music"
47 INK #0,4:OVER #0,0
48 END DEFine 
